9-4 命中判定をしよう

「インベーダー」フォームの「命中判定」ボタンに命中判定させるようにしましょう。プログラムは次のようになります。

// 「命中判定」ボタン
procedure TFormInvader.ButtonHitCheckClick(Sender: TObject);
begin
  if (FormBullet.CheckBoxAlive.Checked = True) and
      (abs(SpinEditX.Value -100) <= 10) and
      (abs(SpinEditY.Value - FormBullet.SpinEditY.Value) <= 10)
    then // 弾が飛んでいて、しかも X, Y 座標ともに10以内の位置にあれば
      begin
        FormBullet.ButtonDestClick(Sender); // 弾の「終了処理」
        ButtonDestClick(Sender); // 自分自身の「終了処理」
      end
  ;
end;

これは、インベーダーの中心から上下左右10ドット以内に弾の先端が入っていたら命中と判定し、インベーダーと弾の両方を消す、という設定になっています。

なお、この「命中判定」ボタンは、インベーダーが移動するたびに「命中したかどうか」を判定されなければなりません。そこで、「移動」ボタンが押されたときの処理の最後に「命中判定」ボタンが押される (ButtonHitCheckClick が呼び出される) ようにします。プログラムを次のように変更してください。(下線部が変更部分です。)

// 「移動」ボタン
procedure TFormInvader.ButtonMoveClick(Sender: TObject);
begin
  if (CheckBoxAlive.Checked = True)
    then // もし「動いている」なら
      begin
        if (SpinEditX.Value + SpinEditSpeed.Value > 180)
            or (SpinEditX.Value + SpinEditSpeed.Value < 20)
          then // もし画面の端にいれば
            begin
              ButtonGoDownClick(Sender); // 「下移動」ボタンを押す
              SpinEditSpeed.Value := -SpinEditSpeed.Value; // 速度反転
            end
          else // もし画面の端以外の場所にいれば
            begin
              ButtonGoHorizontalClick(Sender); // 「左右移動」ボタンを押す
            end
        ;
        ButtonHitCheckClick(Sender); // 「命中判定」ボタンを押す
      end
  ;
end;

また、操作盤上のコンポーネントを操作するだけでゲームできるように (操作盤以外のフォームには触れなくても良いように)、操作盤の「弾発射」ボタンを押すと弾フォームの「初期処理」ボタンを押したことになるようプログラミングします。

// 「弾発射」ボタン
procedure TFormControl.ButtonFireClick(Sender: TObject);
begin
  FormBullet.ButtonConstClick(Sender); // 弾フォームの「初期処理」ボタンを押す
end;

インベーダーフォームの「初期処理」を変更して、インベーダーの出現位置を乱数で決めるようにしましょう。「初期処理」ボタンのイベントハンドラを次のように変更してください (下線部が変更部分です)。

// 「初期処理」ボタン
procedure TFormInvader.ButtonConstClick(Sender: TObject);
begin
  ButtonEraseClick(Sender); // 万一のため今いる場所の絵を消しておく
  SpinEditY.Value := 10; // Y の値の初期化
  SpinEditX.Value := Random(180) + 10; // X 座標を乱数で決める
  SpinEditSpeed.Value := 10; // 速度の値の初期化
  ButtonDrawClick(Sender); // インベーダーを描く
  CheckBoxAlive.Checked := True; // 「動いている」をチェック
end;

この「初期処理」ボタンのプログラムで乱数 Random を使っているので、ここで操作盤の「開始」ボタンを押したときに乱数の初期化もしておくことにしましょう。プログラムを次のように変更してください (下線部が変更部分です)。

// 「開始」ボタン
procedure TFormControl.ButtonStartClick(Sender: TObject);
begin
  Randomize; // 乱数の初期化
  FormInvader.ButtonConstClick(Sender); // インベーダーを出現させる
  TimerMain.Enabled := True; // タイマー開始
end;

これで、インベーダーは1機だけではありますが、一応インベーダーゲームができました。

ここまでのプログラムをダウンロード (D)