【練習問題】

せっかくボスインベーダーを作ったのですから、他のインベーダーとは違う外見にしたいものです。そこで、赤色で描画する手続き Draw を作りましょう。invader_boss ユニットに次のように書き加えてください。

unit invader_boss;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  StdCtrls, Spin, Invader;

type
  TFormInvaderBoss = class(TFormInvader)
  private
    { Private 宣言 }
  protected
    procedure Draw; virtual;
  public
    { Public 宣言 }
    procedure RandomMove; virtual;
  end;

var
  FormInvaderBoss: TFormInvaderBoss;

implementation

uses display, bullet;

{$R *.DFM}

procedure TFormInvaderBoss.RandomMove;
var
  NewSpeed: Integer;
begin
  NewSpeed := GetSpeed + Random(7) - 3;
  SetSpeed(NewSpeed);
  Move;
end;

procedure TFormInvaderBoss.Draw;
begin
  FormDisplay.ImageField.Canvas.Pen.Color := clRed; // 赤でインベーダを描く
  FormDisplay.ImageField.Canvas.MoveTo(X, Y - 3);
  FormDisplay.ImageField.Canvas.LineTo(X - 5, Y + 3);
  FormDisplay.ImageField.Canvas.LineTo(X + 5, Y + 3);
  FormDisplay.ImageField.Canvas.LineTo(X, Y - 3);
end;

end.

実行してみましょう。「未定義の識別子 : 'X'」というエラーが出ましたね。よく考えると「インベーダー」フォームにおける変数 X, Y は private 部にあるのでした。そこで、変数 X, Y を読み出す関数 GetX, GetY を作ります。invader ユニットの冒頭部を次のように変更してください。

type
  TFormInvader = class(TForm)
  private
    { Private 宣言 }
    X: Integer;
    Y: Integer;
    Speed: Integer;
    Alive: Boolean;
  protected
    procedure Draw; virtual;
    procedure Erase; virtual;
    procedure SetSpeed(S: Integer); virtual;
    function GetSpeed: Integer; virtual;
    function GetX: Integer; virtual;
    function GetY: Integer; virtual;
    procedure GoHorizontal; virtual;
    procedure GoDown; virtual;
    procedure HitCheck; virtual;
  public
    { Public 宣言 }
    procedure Move; virtual;
    procedure Init; virtual;
  end;

ユニットの末尾には、関数本体を書き加えます。

// X 呼び出し
function TFormInvader.GetX: Integer;
begin
  GetX := X;
end;

// Y 呼び出し
function TFormInvader.GetY: Integer;
begin
  GetY := Y;
end;

end.

最後に invader_boss ユニットに戻って Draw 手続きを書き換えます。

procedure TFormInvaderBoss.Draw;
begin
  FormDisplay.ImageField.Canvas.Pen.Color := clRed; // 赤でインベーダを描く
  FormDisplay.ImageField.Canvas.MoveTo(GetX, GetY - 3);
  FormDisplay.ImageField.Canvas.LineTo(GetX - 5, GetY + 3);
  FormDisplay.ImageField.Canvas.LineTo(GetX + 5, GetY + 3);
  FormDisplay.ImageField.Canvas.LineTo(GetX, GetY - 3);
end;

実行してみましょう。

---

残念ながらボスインベーダーは赤く表示されません。これは、今作った Draw メソッドとインベーダーフォームに元からある Draw メソッドがかち合っていること (そしてインベーダーフォームに元からある Draw メソッドが優先されていること) が原因です。これを解消するには、後から作った (ボスインベーダーフォーム側の) Draw に virtual の代わりに override (上書き) と指定してやります。invader_boss ユニットの冒頭部を次のように変えてください。

type
  TFormInvaderBoss = class(TFormInvader)
  private
    { Private 宣言 }
  protected
    procedure Draw; override;
  public
    { Public 宣言 }
    procedure RandomMove; virtual;
  end;

実行して動作を確認しましょう。今度は赤いボスインベーダーが現れるはずです。